Root/
1 | #!/usr/bin/perl |
2 | |
3 | # Check the stack usage of functions |
4 | # |
5 | # Copyright Joern Engel <joern@lazybastard.org> |
6 | # Inspired by Linus Torvalds |
7 | # Original idea maybe from Keith Owens |
8 | # s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de> |
9 | # Mips port by Juan Quintela <quintela@mandrakesoft.com> |
10 | # IA64 port via Andreas Dilger |
11 | # Arm port by Holger Schurig |
12 | # sh64 port by Paul Mundt |
13 | # Random bits by Matt Mackall <mpm@selenic.com> |
14 | # M68k port by Geert Uytterhoeven and Andreas Schwab |
15 | # AVR32 port by Haavard Skinnemoen (Atmel) |
16 | # PARISC port by Kyle McMartin <kyle@parisc-linux.org> |
17 | # sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk> |
18 | # |
19 | # Usage: |
20 | # objdump -d vmlinux | scripts/checkstack.pl [arch] |
21 | # |
22 | # TODO : Port to all architectures (one regex per arch) |
23 | |
24 | use strict; |
25 | |
26 | # check for arch |
27 | # |
28 | # $re is used for two matches: |
29 | # $& (whole re) matches the complete objdump line with the stack growth |
30 | # $1 (first bracket) matches the size of the stack growth |
31 | # |
32 | # $dre is similar, but for dynamic stack redutions: |
33 | # $& (whole re) matches the complete objdump line with the stack growth |
34 | # $1 (first bracket) matches the dynamic amount of the stack growth |
35 | # |
36 | # use anything else and feel the pain ;) |
37 | my (@stack, $re, $dre, $x, $xs, $funcre); |
38 | { |
39 | my $arch = shift; |
40 | if ($arch eq "") { |
41 | $arch = `uname -m`; |
42 | chomp($arch); |
43 | } |
44 | |
45 | $x = "[0-9a-f]"; # hex character |
46 | $xs = "[0-9a-f ]"; # hex character or space |
47 | $funcre = qr/^$x* <(.*)>:$/; |
48 | if ($arch eq 'arm') { |
49 | #c0008ffc: e24dd064 sub sp, sp, #100 ; 0x64 |
50 | $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o; |
51 | } elsif ($arch eq 'avr32') { |
52 | #8000008a: 20 1d sub sp,4 |
53 | #80000ca8: fa cd 05 b0 sub sp,sp,1456 |
54 | $re = qr/^.*sub.*sp.*,([0-9]{1,8})/o; |
55 | } elsif ($arch =~ /^i[3456]86$/) { |
56 | #c0105234: 81 ec ac 05 00 00 sub $0x5ac,%esp |
57 | $re = qr/^.*[as][du][db] \$(0x$x{1,8}),\%esp$/o; |
58 | $dre = qr/^.*[as][du][db] (%.*),\%esp$/o; |
59 | } elsif ($arch eq 'x86_64') { |
60 | # 2f60: 48 81 ec e8 05 00 00 sub $0x5e8,%rsp |
61 | $re = qr/^.*[as][du][db] \$(0x$x{1,8}),\%rsp$/o; |
62 | $dre = qr/^.*[as][du][db] (\%.*),\%rsp$/o; |
63 | } elsif ($arch eq 'ia64') { |
64 | #e0000000044011fc: 01 0f fc 8c adds r12=-384,r12 |
65 | $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o; |
66 | } elsif ($arch eq 'm68k') { |
67 | # 2b6c: 4e56 fb70 linkw %fp,#-1168 |
68 | # 1df770: defc ffe4 addaw #-28,%sp |
69 | $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o; |
70 | } elsif ($arch eq 'metag') { |
71 | #400026fc: 40 00 00 82 ADD A0StP,A0StP,#0x8 |
72 | $re = qr/.*ADD.*A0StP,A0StP,\#(0x$x{1,8})/o; |
73 | $funcre = qr/^$x* <[^\$](.*)>:$/; |
74 | } elsif ($arch eq 'mips64') { |
75 | #8800402c: 67bdfff0 daddiu sp,sp,-16 |
76 | $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o; |
77 | } elsif ($arch eq 'mips') { |
78 | #88003254: 27bdffe0 addiu sp,sp,-32 |
79 | $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o; |
80 | } elsif ($arch eq 'parisc' || $arch eq 'parisc64') { |
81 | $re = qr/.*ldo ($x{1,8})\(sp\),sp/o; |
82 | } elsif ($arch eq 'ppc') { |
83 | #c00029f4: 94 21 ff 30 stwu r1,-208(r1) |
84 | $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o; |
85 | } elsif ($arch eq 'ppc64') { |
86 | #XXX |
87 | $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o; |
88 | } elsif ($arch eq 'powerpc') { |
89 | $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o; |
90 | } elsif ($arch =~ /^s390x?$/) { |
91 | # 11160: a7 fb ff 60 aghi %r15,-160 |
92 | # or |
93 | # 100092: e3 f0 ff c8 ff 71 lay %r15,-56(%r15) |
94 | $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2}) |
95 | (?:\(\%r15\))?$/ox; |
96 | } elsif ($arch =~ /^sh64$/) { |
97 | #XXX: we only check for the immediate case presently, |
98 | # though we will want to check for the movi/sub |
99 | # pair for larger users. -- PFM. |
100 | #a00048e0: d4fc40f0 addi.l r15,-240,r15 |
101 | $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o; |
102 | } elsif ($arch =~ /^blackfin$/) { |
103 | # 0: 00 e8 38 01 LINK 0x4e0; |
104 | $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o; |
105 | } elsif ($arch eq 'sparc' || $arch eq 'sparc64') { |
106 | # f0019d10: 9d e3 bf 90 save %sp, -112, %sp |
107 | $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o; |
108 | } else { |
109 | print("wrong or unknown architecture \"$arch\"\n"); |
110 | exit |
111 | } |
112 | } |
113 | |
114 | # |
115 | # main() |
116 | # |
117 | my ($func, $file, $lastslash); |
118 | |
119 | while (my $line = <STDIN>) { |
120 | if ($line =~ m/$funcre/) { |
121 | $func = $1; |
122 | } |
123 | elsif ($line =~ m/(.*):\s*file format/) { |
124 | $file = $1; |
125 | $file =~ s/\.ko//; |
126 | $lastslash = rindex($file, "/"); |
127 | if ($lastslash != -1) { |
128 | $file = substr($file, $lastslash + 1); |
129 | } |
130 | } |
131 | elsif ($line =~ m/$re/) { |
132 | my $size = $1; |
133 | $size = hex($size) if ($size =~ /^0x/); |
134 | |
135 | if ($size > 0xf0000000) { |
136 | $size = - $size; |
137 | $size += 0x80000000; |
138 | $size += 0x80000000; |
139 | } |
140 | next if ($size > 0x10000000); |
141 | |
142 | next if $line !~ m/^($xs*)/; |
143 | my $addr = $1; |
144 | $addr =~ s/ /0/g; |
145 | $addr = "0x$addr"; |
146 | |
147 | my $intro = "$addr $func [$file]:"; |
148 | my $padlen = 56 - length($intro); |
149 | while ($padlen > 0) { |
150 | $intro .= ' '; |
151 | $padlen -= 8; |
152 | } |
153 | next if ($size < 100); |
154 | push @stack, "$intro$size\n"; |
155 | } |
156 | elsif (defined $dre && $line =~ m/$dre/) { |
157 | my $size = "Dynamic ($1)"; |
158 | |
159 | next if $line !~ m/^($xs*)/; |
160 | my $addr = $1; |
161 | $addr =~ s/ /0/g; |
162 | $addr = "0x$addr"; |
163 | |
164 | my $intro = "$addr $func [$file]:"; |
165 | my $padlen = 56 - length($intro); |
166 | while ($padlen > 0) { |
167 | $intro .= ' '; |
168 | $padlen -= 8; |
169 | } |
170 | push @stack, "$intro$size\n"; |
171 | } |
172 | } |
173 | |
174 | # Sort output by size (last field) |
175 | print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack; |
176 | |
177 |
Branches:
ben-wpan
ben-wpan-stefan
javiroman/ks7010
jz-2.6.34
jz-2.6.34-rc5
jz-2.6.34-rc6
jz-2.6.34-rc7
jz-2.6.35
jz-2.6.36
jz-2.6.37
jz-2.6.38
jz-2.6.39
jz-3.0
jz-3.1
jz-3.11
jz-3.12
jz-3.13
jz-3.15
jz-3.16
jz-3.18-dt
jz-3.2
jz-3.3
jz-3.4
jz-3.5
jz-3.6
jz-3.6-rc2-pwm
jz-3.9
jz-3.9-clk
jz-3.9-rc8
jz47xx
jz47xx-2.6.38
master
Tags:
od-2011-09-04
od-2011-09-18
v2.6.34-rc5
v2.6.34-rc6
v2.6.34-rc7
v3.9